home *** CD-ROM | disk | FTP | other *** search
/ PsL Monthly 1993 December / PSL Monthly Shareware CD-ROM (December 1993).iso / prgmming / dos / c / driver.com / DRIVER.ASM < prev    next >
Encoding:
Assembly Source File  |  1991-07-09  |  4.2 KB  |  137 lines
  1. ;
  2. ; This file provides the lowlevel interface needed for creating a DOS
  3. ; device driver. This module is designed to be assembled using Borlands
  4. ; TASM. All you need to do is modify the C module _handler to suit your
  5. ; needs and then link everything together.
  6. ;
  7. ; As usual you may use these modules as you please without paying me anything
  8. ; unless of course you want to pay me, I could always use another trip to the
  9. ; Bahamas.  If you would like to ask me anything just send E-Mail to
  10. ; 76207,674 
  11.  
  12. DONE        equ    0100h    ; operation complete bit
  13.  
  14.         .model    small    ; memory models must match between all modules
  15.         .286        ; you could change this to what ever you wish
  16.         .code        ; simplified segment directives make segments
  17.                 ; match C segment directives
  18. extrn        _handler:near    ; external C module
  19.  
  20.         org    0    ; all device drivers start at location 0
  21. ;
  22. ; the following header is required in all device drivers
  23. ; 
  24. header        dd    -1    ; pointer to next driver in the chain
  25. attribute    dw    8000h    ; character device 
  26.         dw    offset strategy        ; offset to stratgey routine
  27.         dw    offset interrupt    ; offset to interrupt routine
  28.         db    'GENERIC$'        ; driver name 8 bytes padded
  29. ;
  30. ; end of header
  31. ;
  32.  
  33. ;
  34. ; local data
  35. ;        
  36. request_header    dd    ?    ; address of DOS request header
  37. oldss        dw    ?    ; old stack segment
  38. oldsp        dw    ?    ; old stack pointer
  39.  
  40. local_stack    db    128 dup ('stack   ')    ; 1k local stack
  41. tos        dw    ?            ; top of stack
  42.  
  43. ;
  44. ; The strategy routine just stores the address of the request header.
  45. ; When DOS calls the device driver it first calls the strategy routine
  46. ;
  47. strategy    proc    far
  48.         mov    word ptr cs:[request_header],bx
  49.         mov    word ptr cs:[request_header+2],es
  50.         ret
  51. strategy    endp
  52.  
  53. ;
  54. ; DOS calls the interrupt routine after the stratgey routine returns
  55. ;        
  56. interrupt    proc    far    
  57.         pushf        ; we need to save the state of the machine
  58.         push    ax    ; since we're being called from the kernel
  59.         push    bx
  60.         push    cx
  61.         push    dx
  62.         push    ds
  63.         push    es
  64.         push    si
  65.         push    di
  66.         push    bp
  67.  
  68. ;
  69. ; we establish our own data segment and make it equal to the code segment
  70. ; since our local data is located in code segment
  71. ;
  72.         push    cs
  73.         pop    ds        
  74. ;
  75. ; Load es:bx with the address of the request header, DOS passes information
  76. ; to the device driver through the request header
  77. ;        
  78.         les    bx,[request_header]
  79.  
  80. ;
  81. ; Now we save the current stack and setup our own stack incase the calling
  82. ; program doesn't have enough stack space available for the driver
  83. ;
  84.         mov    word ptr oldss,ss    ; save stack segment
  85.         mov    word ptr oldsp,sp    ; save stack pointer
  86.         mov    ax,cs            ; get our stack segment
  87.         mov    ss,ax            ; establish stack
  88.         mov    sp,offset tos - 2    ; and pointer
  89.  
  90. ; Now push the request header address on the stack and and call the
  91. ; C routine using the TASM language independent calling feature
  92. ; Just call the routine specifing the language followed by the parms
  93. ; TASM will push the parms on the stack in the correct order and adjust
  94. ; the stack when the routine returns
  95. ;
  96.         call    _handler C,BX,ES    
  97. ;        
  98. ; Note: on 80x86 machines segment:offset memory variables are referenced in
  99. ; reverse order so the variable addressed by es:bx is stored in memory with
  100. ; bx in the first word and es in the second word. In the above call bx is 
  101. ; before es because we pass variables to C functions on the stack which is
  102. ; just physical memory referenced by SS and SP
  103. ;
  104. ; AX contains status code returned from _handler which is declare as 
  105. ; int handler(RequestHeader far *) in the C file
  106. ;
  107. ; Now that we are back we must restore the original stack and finish
  108. ; processing the driver code
  109. ;
  110.         push    cs    ; let's restore our data segment since it got
  111.         pop    ds    ; changed in the C module
  112.  
  113.         mov    ss,word ptr oldss    ; restore original stack seg
  114.         mov    sp,word ptr oldsp    ; and stack pointer
  115.  
  116. ;
  117. ; The remaining code restores the machine state and then returns telling
  118. ; DOS that the operation is complete
  119. ;
  120. finish:        les    bx,[request_header] ; get address of request header
  121.         or    ax,DONE        ; set completion bit
  122.         mov    es:[bx]+3,ax    ; store it in the request header
  123.         pop    bp        ; restore all registers
  124.         pop    di
  125.         pop    si
  126.         pop    es
  127.         pop    ds
  128.         pop    dx
  129.         pop    cx
  130.         pop    bx
  131.         pop    ax
  132.         popf
  133.         ret    ; and return to DOS, this is not a real interrupt
  134.             ; routine so we don't need an IRET
  135. interrupt    endp
  136.  
  137.         end